Cart pendulum

This problem involves swinging up a pendulum mounted on a cart, a classical underactuated system. The goal is to move the pendulum from its downward equilibrium to the upright position while controlling the horizontal motion of the cart, in minimum time.

System Dynamics

The system has four states and one control:

• \[x\]

  : cart position

• \[v\]

  : cart velocity

• \[\theta\]

  : pendulum angle from downward vertical

• \[\omega\]

  : pendulum angular velocity

• \[F_{\rm ex}\]

  : horizontal force applied to the cart (control)

The dynamics are expressed as

\[\dot{x} = v\]

\[\dot{v} = -\frac{1}{J} \, c\]

\[\dot{\theta} = \omega\]

\[\dot{\omega} = \alpha(\dot{v})\]

where

\[\alpha(ddx) = \frac{0.5 \, L \, m}{I + 0.25 \, m L^2} \big(-ddx \cos\theta - g \sin\theta\big)\]

\[\text{ddCOG} = L \, \omega \, [-\sin\theta, \cos\theta] + \frac{L}{2} \,[\cos\theta, \sin\theta] \, \alpha(ddx) + [ddx,0]\]

\[\text{FXFY} = m \, \text{ddCOG} + [0, m g]\]

\[c = -\text{FXFY}_x + F_{\rm ex} - m_{\rm cart} ddx - J ddx\]

Here, $J$ represents the effective mass of the cart, $m$ and $m_{\rm cart}$ are the pendulum and cart masses, $L$ is the pendulum length, and $I$ its moment of inertia. The variable $ddx$ is an auxiliary variable related to the cart acceleration used for the dynamics formulation.

Boundary Conditions

• Initial conditions:

\[x(0) = 0, \quad \theta(0) = 0, \quad \omega(0) = 0\]

• Final conditions:

\[\theta(T) = \pi, \quad \omega(T) = 0\]

• Cart position and velocity constraints:

\[|x(t)| \le 1, \quad |v(t)| \le 2\]

• Control limits:

\[|F_{\rm ex}(t)| \le 5\]

• Time horizon:

\[T \ge 0.1\]

Objective

The goal is to minimize the final time $T$:

\[J = T \to \min\]

subject to the dynamics, boundary conditions, and state/control constraints.

References

• Vanroye, L., Sathya, A., De Schutter, J., & Decré, W. (2023). FATROP: A Fast Constrained Optimal Control Problem Solver for Robot Trajectory Optimization and Control. arXiv preprint arXiv:2303.16746. Retrieved from https://arxiv.org/pdf/2303.16746
• Åström, K. J., & Furuta, K. (2000). Swinging up a pendulum by energy control. Automatica, 36(2), 287–295.
• Lipp, T., & Boyd, S. (2014). Variations and extensions of the cart-pole swing-up problem. Stanford University Technical Report.

Packages

Import all necessary packages and define DataFrames to store information about the problem and resolution results.

using OptimalControlProblems    # to access the Beam model
using OptimalControl            # to import the OptimalControl model
using NLPModelsIpopt            # to solve the model with Ipopt
import DataFrames: DataFrame    # to store data
using NLPModels                 # to retrieve data from the NLP solution
using Plots                     # to plot the trajectories
using Plots.PlotMeasures        # for leftmargin, bottommargin
using JuMP                      # to import the JuMP model
using Ipopt                     # to solve the JuMP model with Ipopt

data_pb = DataFrame(            # to store data about the problem
    Problem=Symbol[],
    Grid_Size=Int[],
    Variables=Int[],
    Constraints=Int[],
)

data_re = DataFrame(            # to store data about the resolutions
    Model=Symbol[],
    Flag=Any[],
    Iterations=Int[],
    Objective=Float64[],
)

Initial guess

The initial guess (or first iterate) can be visualised by running the solver with max_iter=0. Here is the initial guess.

function plot_initial_guess(problem)

    # dimensions
    x_vars = metadata[problem][:state_name]
    u_vars = metadata[problem][:control_name]
    n = length(x_vars) # number of states
    m = length(u_vars) # number of controls

    # import OptimalControl model
    docp = eval(problem)(OptimalControlBackend())
    nlp_oc = nlp_model(docp)

    # solve
    nlp_oc_sol = NLPModelsIpopt.ipopt(nlp_oc; max_iter=0)

    # build an optimal control solution
    ocp_sol = build_ocp_solution(docp, nlp_oc_sol)

    # plot the OptimalControl solution
    plt = plot(
        ocp_sol;
        state_style=(color=1,),
        costate_style=(color=1, legend=:none),
        control_style=(color=1, legend=:none),
        path_style=(color=1, legend=:none),
        dual_style=(color=1, legend=:none),
        size=(816, 220*(n+m)),
        label="OptimalControl",
        leftmargin=20mm,
    )
    for i in 2:n
        plot!(plt[i]; legend=:none)
    end

    # import JuMP model
    nlp_jp = eval(problem)(JuMPBackend())

    # solve
    set_optimizer(nlp_jp, Ipopt.Optimizer)
    set_optimizer_attribute(nlp_jp, "max_iter", 0)
    optimize!(nlp_jp)

    # plot
    t = time_grid(problem, nlp_jp)     # t0, ..., tN = tf
    x = state(problem, nlp_jp)         # function of time
    u = control(problem, nlp_jp)       # function of time
    p = costate(problem, nlp_jp)       # function of time

    for i in 1:n # state
        label = i == 1 ? "JuMP" : :none
        plot!(plt[i], t, t -> x(t)[i]; color=2, linestyle=:dash, label=label)
    end

    for i in 1:n # costate
        plot!(plt[n+i], t, t -> -p(t)[i]; color=2, linestyle=:dash, label=:none)
    end

    for i in 1:m # control
        plot!(plt[2n+i], t, t -> u(t)[i]; color=2, linestyle=:dash, label=:none)
    end

    return plt
end

plot_initial_guess(:cart_pendulum)

Solve the problem

OptimalControl model

Import the OptimalControl model and solve it.

# import DOCP model
docp = cart_pendulum(OptimalControlBackend())

# get NLP model
nlp_oc = nlp_model(docp)

# solve
nlp_oc_sol = NLPModelsIpopt.ipopt(
    nlp_oc;
    print_level=4,
    tol=1e-8,
    mu_strategy="adaptive",
    sb="yes",
)

Total number of variables............................:     2507
                     variables with only lower bounds:        1
                variables with lower and upper bounds:     1503
                     variables with only upper bounds:        0
Total number of equality constraints.................:     2005
Total number of inequality constraints...............:        0
        inequality constraints with only lower bounds:        0
   inequality constraints with lower and upper bounds:        0
        inequality constraints with only upper bounds:        0


Number of Iterations....: 386

                                   (scaled)                 (unscaled)
Objective...............:   1.7439655750261349e+00    1.7439655750261349e+00
Dual infeasibility......:   3.7154039003381434e-10    3.7154039003381434e-10
Constraint violation....:   2.1820550921702875e-10    2.1820550921702875e-10
Variable bound violation:   3.8430698623415083e-08    3.8430698623415083e-08
Complementarity.........:   3.7504119987994165e-11    3.7504119987994165e-11
Overall NLP error.......:   3.7154039003381434e-10    3.7154039003381434e-10


Number of objective function evaluations             = 421
Number of objective gradient evaluations             = 359
Number of equality constraint evaluations            = 421
Number of inequality constraint evaluations          = 0
Number of equality constraint Jacobian evaluations   = 390
Number of inequality constraint Jacobian evaluations = 0
Number of Lagrangian Hessian evaluations             = 386
Total seconds in IPOPT                               = 7.477

EXIT: Optimal Solution Found.

The problem has the following numbers of steps, variables and constraints.

push!(data_pb,
    (
        Problem=:cart_pendulum,
        Grid_Size=metadata[:cart_pendulum][:N],
        Variables=get_nvar(nlp_oc),
        Constraints=get_ncon(nlp_oc),
    )
)

JuMP model

Import the JuMP model and solve it.

# import model
nlp_jp = cart_pendulum(JuMPBackend())

# solve
set_optimizer(nlp_jp, Ipopt.Optimizer)
set_optimizer_attribute(nlp_jp, "print_level", 4)
set_optimizer_attribute(nlp_jp, "tol", 1e-8)
set_optimizer_attribute(nlp_jp, "mu_strategy", "adaptive")
set_optimizer_attribute(nlp_jp, "linear_solver", "mumps")
set_optimizer_attribute(nlp_jp, "sb", "yes")
optimize!(nlp_jp)

Total number of variables............................:     2507
                     variables with only lower bounds:        1
                variables with lower and upper bounds:     1503
                     variables with only upper bounds:        0
Total number of equality constraints.................:     2005
Total number of inequality constraints...............:        0
        inequality constraints with only lower bounds:        0
   inequality constraints with lower and upper bounds:        0
        inequality constraints with only upper bounds:        0


Number of Iterations....: 290

                                   (scaled)                 (unscaled)
Objective...............:   1.7439655750387701e+00    1.7439655750387701e+00
Dual infeasibility......:   2.5948068086562026e-10    2.5948068086562026e-10
Constraint violation....:   1.6042195349896815e-10    1.6042195349896815e-10
Variable bound violation:   3.8430657767207776e-08    3.8430657767207776e-08
Complementarity.........:   2.9764515309179606e-11    2.9764515309179606e-11
Overall NLP error.......:   2.5948068086562026e-10    2.5948068086562026e-10


Number of objective function evaluations             = 333
Number of objective gradient evaluations             = 245
Number of equality constraint evaluations            = 333
Number of inequality constraint evaluations          = 0
Number of equality constraint Jacobian evaluations   = 295
Number of inequality constraint Jacobian evaluations = 0
Number of Lagrangian Hessian evaluations             = 290
Total seconds in IPOPT                               = 5.066

EXIT: Optimal Solution Found.

Numerical comparisons

Let's get the flag, the number of iterations and the objective value from the resolutions.

# from OptimalControl model
push!(data_re,
    (
        Model=:OptimalControl,
        Flag=nlp_oc_sol.status,
        Iterations=nlp_oc_sol.iter,
        Objective=nlp_oc_sol.objective,
    )
)

# from JuMP model
push!(data_re,
    (
        Model=:JuMP,
        Flag=termination_status(nlp_jp),
        Iterations=barrier_iterations(nlp_jp),
        Objective=objective_value(nlp_jp),
    )
)

We compare the OptimalControl and JuMP solutions in terms of the number of iterations, the $L^2$-norm of the differences in the state, control, and variable, as well as the objective values. Both absolute and relative errors are reported.

function L2_norm(T, X)
    # T and X are supposed to be one dimensional
    s = 0.0
    for i in 1:(length(T) - 1)
        s += 0.5 * (X[i]^2 + X[i + 1]^2) * (T[i + 1]-T[i])
    end
    return √(s)
end

function numerical_comparison(problem, docp, nlp_oc_sol, nlp_jp)

    # get relevant data from OptimalControl model
    ocp_sol = build_ocp_solution(docp, nlp_oc_sol) # build an ocp solution
    t_oc = time_grid(ocp_sol)
    x_oc = state(ocp_sol).(t_oc)
    u_oc = control(ocp_sol).(t_oc)
    v_oc = variable(ocp_sol)
    o_oc = objective(ocp_sol)
    i_oc = iterations(ocp_sol)

    # get relevant data from JuMP model
    t_jp = time_grid(problem, nlp_jp)
    x_jp = state(problem, nlp_jp).(t_jp)
    u_jp = control(problem, nlp_jp).(t_jp)
    o_jp = objective(problem, nlp_jp)
    v_jp = variable(problem, nlp_jp)
    i_jp = iterations(problem, nlp_jp)

    x_vars = metadata[problem][:state_name]
    u_vars = metadata[problem][:control_name]
    v_vars = metadata[problem][:variable_name]

    println("┌─ ", string(problem))
    println("│")

    # number of iterations
    println("├─  Number of iterations")
    println("│")
    println("│     OptimalControl : ", i_oc)
    println("│     JuMP           : ", i_jp)
    println("│")

    # state
    for i in eachindex(x_vars)
        xi_oc = [x_oc[k][i] for k in eachindex(t_oc)]
        xi_jp = [x_jp[k][i] for k in eachindex(t_jp)]
        L2_oc = L2_norm(t_oc, xi_oc)
        L2_jp = L2_norm(t_oc, xi_jp)
        L2_ae = L2_norm(t_oc, xi_oc-xi_jp)
        L2_re = L2_ae/(0.5*(L2_oc + L2_jp))

        println("├─  State $(x_vars[i]) (L2 norm)")
        println("│")
        #println("│     OptimalControl : ", L2_oc)
        #println("│     JuMP           : ", L2_jp)
        println("│     Absolute error : ", L2_ae)
        println("│     Relative error : ", L2_re)
        println("│")
    end

    # control
    for i in eachindex(u_vars)
        ui_oc = [u_oc[k][i] for k in eachindex(t_oc)]
        ui_jp = [u_jp[k][i] for k in eachindex(t_jp)]
        L2_oc = L2_norm(t_oc, ui_oc)
        L2_jp = L2_norm(t_oc, ui_jp)
        L2_ae = L2_norm(t_oc, ui_oc-ui_jp)
        L2_re = L2_ae/(0.5*(L2_oc + L2_jp))

        println("├─  Control $(u_vars[i]) (L2 norm)")
        println("│")
        #println("│     OptimalControl : ", L2_oc)
        #println("│     JuMP           : ", L2_jp)
        println("│     Absolute error : ", L2_ae)
        println("│     Relative error : ", L2_re)
        println("│")
    end

    # variable
    if !isnothing(v_vars)
        for i in eachindex(v_vars)
            vi_oc = v_oc[i]
            vi_jp = v_jp[i]
            vi_ae = abs(vi_oc-vi_jp)
            vi_re = vi_ae/(0.5*(abs(vi_oc) + abs(vi_jp)))

            println("├─  Variable $(v_vars[i])")
            println("│")
            #println("│     OptimalControl : ", vi_oc)
            #println("│     JuMP           : ", vi_jp)
            println("│     Absolute error : ", vi_ae)
            println("│     Relative error : ", vi_re)
            println("│")
        end
    end

    # objective
    o_ae = abs(o_oc-o_jp)
    o_re = o_ae/(0.5*(abs(o_oc) + abs(o_jp)))

    println("├─  objective")
    println("│")
    #println("│     OptimalControl : ", o_oc)
    #println("│     JuMP           : ", o_jp)
    println("│     Absolute error : ", o_ae)
    println("│     Relative error : ", o_re)
    println("│")
    println("└─")

    return nothing
end

numerical_comparison(:cart_pendulum, docp, nlp_oc_sol, nlp_jp)

┌─ cart_pendulum
│
├─  Number of iterations
│
│     OptimalControl : 386
│     JuMP           : 290
│
├─  State x (L2 norm)
│
│     Absolute error : 2.5919422876738248e-8
│     Relative error : 3.280850793366343e-8
│
├─  State v (L2 norm)
│
│     Absolute error : 1.7039581836315716e-6
│     Relative error : 1.0465303459460474e-6
│
├─  State θ (L2 norm)
│
│     Absolute error : 2.3954091071462237e-8
│     Relative error : 1.1694602299298485e-8
│
├─  State ω (L2 norm)
│
│     Absolute error : 1.3652314337009033e-6
│     Relative error : 3.007062455529096e-7
│
├─  Control Fex (L2 norm)
│
│     Absolute error : 0.003989596985046297
│     Relative error : 0.0006167265531643969
│
├─  Variable tf
│
│     Absolute error : 1.2635226198653982e-11
│     Relative error : 7.245112162502898e-12
│
├─  Variable ddx
│
│     Absolute error : 2.3069118688587298e-7
│     Relative error : 8.411350785863157e-6
│
├─  objective
│
│     Absolute error : 1.2635226198653982e-11
│     Relative error : 7.245112162502898e-12
│
└─

Plot the solutions

Visualise states, costates, and controls from the OptimalControl and JuMP solutions:

# build an ocp solution to use the plot from OptimalControl package
ocp_sol = build_ocp_solution(docp, nlp_oc_sol)

# dimensions
n = state_dimension(ocp_sol)   # or length(metadata[:cart_pendulum][:state_name])
m = control_dimension(ocp_sol) # or length(metadata[:cart_pendulum][:control_name])

# from OptimalControl solution
plt = plot(
    ocp_sol;
    state_style=(color=1,),
    costate_style=(color=1, legend=:none),
    control_style=(color=1, legend=:none),
    path_style=(color=1, legend=:none),
    dual_style=(color=1, legend=:none),
    size=(816, 240*(n+m)),
    label="OptimalControl",
    leftmargin=20mm,
)
for i in 2:n
    plot!(plt[i]; legend=:none)
end

# from JuMP solution
t = time_grid(:cart_pendulum, nlp_jp)     # t0, ..., tN = tf
x = state(:cart_pendulum, nlp_jp)         # function of time
u = control(:cart_pendulum, nlp_jp)       # function of time
p = costate(:cart_pendulum, nlp_jp)       # function of time

for i in 1:n # state
    label = i == 1 ? "JuMP" : :none
    plot!(plt[i], t, t -> x(t)[i]; color=2, linestyle=:dash, label=label)
end

for i in 1:n # costate
    plot!(plt[n+i], t, t -> -p(t)[i]; color=2, linestyle=:dash, label=:none)
end

for i in 1:m # control
    plot!(plt[2n+i], t, t -> u(t)[i]; color=2, linestyle=:dash, label=:none)
end