Jackson

This problem models a simple system of chemical reactions introduced in Jackson (1968) and later discussed by Biegler (2010):

\[A \;\overset{1}{\rightleftharpoons}\; B \;\overset{2}{\longrightarrow}\; C.\]

The first reaction is reversible ($A \leftrightarrow B$), while the second one is one-sided ($B \to C$). The control variable $u(t)\in [0,1]$ represents the fraction of catalyst allocated between the two reactions:

for $u=1$, the catalyst favours the reversible $A \leftrightarrow B$ pathway,
for $u=0$, the catalyst favours the irreversible $B \to C$ pathway.

The aim is to maximise the production of $C$ at a fixed terminal time $T$.

Problem formulation

Let $a(t), b(t), c(t)$ denote the mole fractions of $A, B, C$ respectively, and $k_1, k_2, k_3$ the kinetic constants. The optimal control problem is

\[\begin{aligned} \max_{u(\cdot)} \quad & c(T) \\ \dot a(t) &= - u(t)\,(k_1 a(t) - k_2 b(t)), \\ \dot b(t) &= \; u(t)\,(k_1 a(t) - k_2 b(t)) - (1-u(t))\,k_3 b(t), \\ \dot c(t) &= (1-u(t))\,k_3 b(t), \\ u(t) &\in [0,1], \\ a(0) &= 1, \quad b(0)=c(0)=0. \end{aligned}\]

The state constraints are $a,b,c \geq 0$, and by invariance one has $a(t)+b(t)+c(t)=1$.

Qualitative behaviour

The Hamiltonian is linear in the control, so the optimal solution typically consists of bang–bang arcs and possibly singular arcs.

For the parameters $k_1=k_3=1$, $k_2=10$, and $T=4$, the optimal control exhibits a bang–singular–bang structure (1 → singular → 0). The singular arc corresponds to an intermediate phase where the catalyst is shared between the two reactions.

Parameter identification (optional extension)

The same model can be extended to parameter estimation: given experimental observations of $a(t), b(t), c(t)$ under a known control input $u(t)$, the unknown kinetic constants $k_1, k_2, k_3$ can be identified using a least-squares fit. Simulated data with added noise reproduce the original parameters with high accuracy (see Table below).

Parameter	True value	Identified value
$k_1$	1	0.998
$k_2$	10	9.97
$k_3$	1	1.001

References

Jackson, E. A. (1968). The existence of singular extremals. Journal of Optimization Theory and Applications.
Biegler, L. T. (2010). Nonlinear Programming: Concepts, Algorithms, and Applications to Chemical Processes. SIAM.
BOCOP repository: https://github.com/control-toolbox/bocop

Packages

Import all necessary packages and define DataFrames to store information about the problem and resolution results.

using OptimalControlProblems    # to access the Beam model
using OptimalControl            # to import the OptimalControl model
using NLPModelsIpopt            # to solve the model with Ipopt
import DataFrames: DataFrame    # to store data
using NLPModels                 # to retrieve data from the NLP solution
using Plots                     # to plot the trajectories
using Plots.PlotMeasures        # for leftmargin, bottommargin
using JuMP                      # to import the JuMP model
using Ipopt                     # to solve the JuMP model with Ipopt

data_pb = DataFrame(            # to store data about the problem
    Problem=Symbol[],
    Grid_Size=Int[],
    Variables=Int[],
    Constraints=Int[],
)

data_re = DataFrame(            # to store data about the resolutions
    Model=Symbol[],
    Flag=Any[],
    Iterations=Int[],
    Objective=Float64[],
)

Initial guess

The initial guess (or first iterate) can be visualised by running the solver with max_iter=0. Here is the initial guess.

Click to unfold and see the code for plotting the initial guess.

function plot_initial_guess(problem)

    # dimensions
    x_vars = metadata[problem][:state_name]
    u_vars = metadata[problem][:control_name]
    n = length(x_vars) # number of states
    m = length(u_vars) # number of controls

    # import OptimalControl model
    docp = eval(problem)(OptimalControlBackend())
    nlp_oc = nlp_model(docp)

    # solve
    nlp_oc_sol = NLPModelsIpopt.ipopt(nlp_oc; max_iter=0)

    # build an optimal control solution
    ocp_sol = build_ocp_solution(docp, nlp_oc_sol)

    # plot the OptimalControl solution
    plt = plot(
        ocp_sol;
        state_style=(color=1,),
        costate_style=(color=1, legend=:none),
        control_style=(color=1, legend=:none),
        path_style=(color=1, legend=:none),
        dual_style=(color=1, legend=:none),
        size=(816, 220*(n+m)),
        label="OptimalControl",
        leftmargin=20mm,
    )
    for i in 2:n
        plot!(plt[i]; legend=:none)
    end

    # import JuMP model
    nlp_jp = eval(problem)(JuMPBackend())

    # solve
    set_optimizer(nlp_jp, Ipopt.Optimizer)
    set_optimizer_attribute(nlp_jp, "max_iter", 0)
    optimize!(nlp_jp)

    # plot
    t = time_grid(problem, nlp_jp)     # t0, ..., tN = tf
    x = state(problem, nlp_jp)         # function of time
    u = control(problem, nlp_jp)       # function of time
    p = costate(problem, nlp_jp)       # function of time

    for i in 1:n # state
        label = i == 1 ? "JuMP" : :none
        plot!(plt[i], t, t -> x(t)[i]; color=2, linestyle=:dash, label=label)
    end

    for i in 1:n # costate
        plot!(plt[n+i], t, t -> -p(t)[i]; color=2, linestyle=:dash, label=:none)
    end

    for i in 1:m # control
        plot!(plt[2n+i], t, t -> u(t)[i]; color=2, linestyle=:dash, label=:none)
    end

    return plt
end

plot_initial_guess(:jackson)

Solve the problem

OptimalControl model

Import the OptimalControl model and solve it.

# import DOCP model
docp = jackson(OptimalControlBackend())

# get NLP model
nlp_oc = nlp_model(docp)

# solve
nlp_oc_sol = NLPModelsIpopt.ipopt(
    nlp_oc;
    print_level=4,
    tol=1e-8,
    mu_strategy="adaptive",
    sb="yes",
)

Total number of variables............................:     2004
                     variables with only lower bounds:        0
                variables with lower and upper bounds:     2004
                     variables with only upper bounds:        0
Total number of equality constraints.................:     1503
Total number of inequality constraints...............:        0
        inequality constraints with only lower bounds:        0
   inequality constraints with lower and upper bounds:        0
        inequality constraints with only upper bounds:        0


Number of Iterations....: 58

                                   (scaled)                 (unscaled)
Objective...............:  -1.9182194736952879e-01   -1.9182194736952879e-01
Dual infeasibility......:   2.4102984187587167e-10    2.4102984187587167e-10
Constraint violation....:   1.6731505070310959e-11    1.6731505070310959e-11
Variable bound violation:   0.0000000000000000e+00    0.0000000000000000e+00
Complementarity.........:   1.0083503424697878e-11    1.0083503424697878e-11
Overall NLP error.......:   2.4102984187587167e-10    2.4102984187587167e-10


Number of objective function evaluations             = 61
Number of objective gradient evaluations             = 59
Number of equality constraint evaluations            = 61
Number of inequality constraint evaluations          = 0
Number of equality constraint Jacobian evaluations   = 59
Number of inequality constraint Jacobian evaluations = 0
Number of Lagrangian Hessian evaluations             = 58
Total seconds in IPOPT                               = 0.796

EXIT: Optimal Solution Found.

The problem has the following numbers of steps, variables and constraints.

push!(data_pb,
    (
        Problem=:jackson,
        Grid_Size=metadata[:jackson][:N],
        Variables=get_nvar(nlp_oc),
        Constraints=get_ncon(nlp_oc),
    )
)

1×4 DataFrame

Row	Problem	Grid_Size	Variables	Constraints
	Symbol	Int64	Int64	Int64
1	jackson	500	2004	1503

JuMP model

Import the JuMP model and solve it.

# import model
nlp_jp = jackson(JuMPBackend())

# solve
set_optimizer(nlp_jp, Ipopt.Optimizer)
set_optimizer_attribute(nlp_jp, "print_level", 4)
set_optimizer_attribute(nlp_jp, "tol", 1e-8)
set_optimizer_attribute(nlp_jp, "mu_strategy", "adaptive")
set_optimizer_attribute(nlp_jp, "linear_solver", "mumps")
set_optimizer_attribute(nlp_jp, "sb", "yes")
optimize!(nlp_jp)

Total number of variables............................:     2004
                     variables with only lower bounds:        0
                variables with lower and upper bounds:     2004
                     variables with only upper bounds:        0
Total number of equality constraints.................:     1503
Total number of inequality constraints...............:        0
        inequality constraints with only lower bounds:        0
   inequality constraints with lower and upper bounds:        0
        inequality constraints with only upper bounds:        0


Number of Iterations....: 58

                                   (scaled)                 (unscaled)
Objective...............:  -1.9182194736952385e-01   -1.9182194736952385e-01
Dual infeasibility......:   2.9182402935198572e-10    2.9182402935198572e-10
Constraint violation....:   2.0279343091941793e-11    2.0279343091941793e-11
Variable bound violation:   1.3976331255584633e-41    1.3976331255584633e-41
Complementarity.........:   1.0083652571771611e-11    1.0083652571771611e-11
Overall NLP error.......:   2.9182402935198572e-10    2.9182402935198572e-10


Number of objective function evaluations             = 61
Number of objective gradient evaluations             = 59
Number of equality constraint evaluations            = 61
Number of inequality constraint evaluations          = 0
Number of equality constraint Jacobian evaluations   = 59
Number of inequality constraint Jacobian evaluations = 0
Number of Lagrangian Hessian evaluations             = 58
Total seconds in IPOPT                               = 0.225

EXIT: Optimal Solution Found.

Numerical comparisons

Let's get the flag, the number of iterations and the objective value from the resolutions.

# from OptimalControl model
push!(data_re,
    (
        Model=:OptimalControl,
        Flag=nlp_oc_sol.status,
        Iterations=nlp_oc_sol.iter,
        Objective=nlp_oc_sol.objective,
    )
)

# from JuMP model
push!(data_re,
    (
        Model=:JuMP,
        Flag=termination_status(nlp_jp),
        Iterations=barrier_iterations(nlp_jp),
        Objective=objective_value(nlp_jp),
    )
)

2×4 DataFrame

Row	Model	Flag	Iterations	Objective
	Symbol	Any	Int64	Float64
1	OptimalControl	first_order	58	-0.191822
2	JuMP	LOCALLY_SOLVED	58	-0.191822

We compare the OptimalControl and JuMP solutions in terms of the number of iterations, the $L^2$-norm of the differences in the state, control, and variable, as well as the objective values. Both absolute and relative errors are reported.

Click to unfold and get the code of the numerical comparison.

function L2_norm(T, X)
    # T and X are supposed to be one dimensional
    s = 0.0
    for i in 1:(length(T) - 1)
        s += 0.5 * (X[i]^2 + X[i + 1]^2) * (T[i + 1]-T[i])
    end
    return √(s)
end

function numerical_comparison(problem, docp, nlp_oc_sol, nlp_jp)

    # get relevant data from OptimalControl model
    ocp_sol = build_ocp_solution(docp, nlp_oc_sol) # build an ocp solution
    t_oc = time_grid(ocp_sol)
    x_oc = state(ocp_sol).(t_oc)
    u_oc = control(ocp_sol).(t_oc)
    v_oc = variable(ocp_sol)
    o_oc = objective(ocp_sol)
    i_oc = iterations(ocp_sol)

    # get relevant data from JuMP model
    t_jp = time_grid(problem, nlp_jp)
    x_jp = state(problem, nlp_jp).(t_jp)
    u_jp = control(problem, nlp_jp).(t_jp)
    o_jp = objective(problem, nlp_jp)
    v_jp = variable(problem, nlp_jp)
    i_jp = iterations(problem, nlp_jp)

    x_vars = metadata[problem][:state_name]
    u_vars = metadata[problem][:control_name]
    v_vars = metadata[problem][:variable_name]

    println("┌─ ", string(problem))
    println("│")

    # number of iterations
    println("├─  Number of iterations")
    println("│")
    println("│     OptimalControl : ", i_oc)
    println("│     JuMP           : ", i_jp)
    println("│")

    # state
    for i in eachindex(x_vars)
        xi_oc = [x_oc[k][i] for k in eachindex(t_oc)]
        xi_jp = [x_jp[k][i] for k in eachindex(t_jp)]
        L2_oc = L2_norm(t_oc, xi_oc)
        L2_jp = L2_norm(t_oc, xi_jp)
        L2_ae = L2_norm(t_oc, xi_oc-xi_jp)
        L2_re = L2_ae/(0.5*(L2_oc + L2_jp))

        println("├─  State $(x_vars[i]) (L2 norm)")
        println("│")
        #println("│     OptimalControl : ", L2_oc)
        #println("│     JuMP           : ", L2_jp)
        println("│     Absolute error : ", L2_ae)
        println("│     Relative error : ", L2_re)
        println("│")
    end

    # control
    for i in eachindex(u_vars)
        ui_oc = [u_oc[k][i] for k in eachindex(t_oc)]
        ui_jp = [u_jp[k][i] for k in eachindex(t_jp)]
        L2_oc = L2_norm(t_oc, ui_oc)
        L2_jp = L2_norm(t_oc, ui_jp)
        L2_ae = L2_norm(t_oc, ui_oc-ui_jp)
        L2_re = L2_ae/(0.5*(L2_oc + L2_jp))

        println("├─  Control $(u_vars[i]) (L2 norm)")
        println("│")
        #println("│     OptimalControl : ", L2_oc)
        #println("│     JuMP           : ", L2_jp)
        println("│     Absolute error : ", L2_ae)
        println("│     Relative error : ", L2_re)
        println("│")
    end

    # variable
    if !isnothing(v_vars)
        for i in eachindex(v_vars)
            vi_oc = v_oc[i]
            vi_jp = v_jp[i]
            vi_ae = abs(vi_oc-vi_jp)
            vi_re = vi_ae/(0.5*(abs(vi_oc) + abs(vi_jp)))

            println("├─  Variable $(v_vars[i])")
            println("│")
            #println("│     OptimalControl : ", vi_oc)
            #println("│     JuMP           : ", vi_jp)
            println("│     Absolute error : ", vi_ae)
            println("│     Relative error : ", vi_re)
            println("│")
        end
    end

    # objective
    o_ae = abs(o_oc-o_jp)
    o_re = o_ae/(0.5*(abs(o_oc) + abs(o_jp)))

    println("├─  objective")
    println("│")
    #println("│     OptimalControl : ", o_oc)
    #println("│     JuMP           : ", o_jp)
    println("│     Absolute error : ", o_ae)
    println("│     Relative error : ", o_re)
    println("│")
    println("└─")

    return nothing
end

numerical_comparison(:jackson, docp, nlp_oc_sol, nlp_jp)

┌─ jackson
│
├─  Number of iterations
│
│     OptimalControl : 58
│     JuMP           : 58
│
├─  State a (L2 norm)
│
│     Absolute error : 1.6322011857154782e-10
│     Relative error : 9.668379090827973e-11
│
├─  State b (L2 norm)
│
│     Absolute error : 2.1484278568743313e-10
│     Relative error : 1.7073362270391798e-9
│
├─  State x3 (L2 norm)
│
│     Absolute error : 5.168228745284037e-11
│     Relative error : 2.331095207007575e-10
│
├─  Control u (L2 norm)
│
│     Absolute error : 1.1498043800912417e-6
│     Relative error : 1.6229730620986356e-6
│
├─  objective
│
│     Absolute error : 4.9404924595819466e-15
│     Relative error : 2.5755616222916185e-14
│
└─

Plot the solutions

Visualise states, costates, and controls from the OptimalControl and JuMP solutions:

# build an ocp solution to use the plot from OptimalControl package
ocp_sol = build_ocp_solution(docp, nlp_oc_sol)

# dimensions
n = state_dimension(ocp_sol)   # or length(metadata[:jackson][:state_name])
m = control_dimension(ocp_sol) # or length(metadata[:jackson][:control_name])

# from OptimalControl solution
plt = plot(
    ocp_sol;
    state_style=(color=1,),
    costate_style=(color=1, legend=:none),
    control_style=(color=1, legend=:none),
    path_style=(color=1, legend=:none),
    dual_style=(color=1, legend=:none),
    size=(816, 240*(n+m)),
    label="OptimalControl",
    leftmargin=20mm,
)
for i in 2:n
    plot!(plt[i]; legend=:none)
end

# from JuMP solution
t = time_grid(:jackson, nlp_jp)     # t0, ..., tN = tf
x = state(:jackson, nlp_jp)         # function of time
u = control(:jackson, nlp_jp)       # function of time
p = costate(:jackson, nlp_jp)       # function of time

for i in 1:n # state
    label = i == 1 ? "JuMP" : :none
    plot!(plt[i], t, t -> x(t)[i]; color=2, linestyle=:dash, label=label)
end

for i in 1:n # costate
    plot!(plt[n+i], t, t -> -p(t)[i]; color=2, linestyle=:dash, label=:none)
end

for i in 1:m # control
    plot!(plt[2n+i], t, t -> u(t)[i]; color=2, linestyle=:dash, label=:none)
end